**Linked Economy Ontology Cookbook**

Πίνακας περιεχομένων

[Πρόλογος 3](#_Toc435789657)

[Forbes 2000 4](#_Toc435789658)

[Κλάσεις (Classes) 4](#_Toc435789659)

[FOAF 4](#_Toc435789660)

[Good Relations 4](#_Toc435789661)

[Organization 4](#_Toc435789662)

[SKOS 4](#_Toc435789663)

[Registered Organization 4](#_Toc435789664)

[Linked Economy 4](#_Toc435789665)

[Linked Economy Geo 4](#_Toc435789666)

[Ιδιότητες Αντικειμένων (Object Properties) 4](#_Toc435789667)

[Linked Economy 5](#_Toc435789668)

[Ιδιότητες Τύπου Δεδομένων (Datatype Properties) 5](#_Toc435789669)

[Good Relations 5](#_Toc435789670)

[SKOS 5](#_Toc435789671)

[Linked Economy 5](#_Toc435789672)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 5](#_Toc435789673)

[Στοιχεία Εταιρείας της λίστας Forbes 5](#_Toc435789674)

[Σχετιζόμενες Εταιρειες Εταιρείας της λίστας Forbes 6](#_Toc435789675)

[Πλήθος Σχετιζόμενων Εταιρειών Εταιρείας της λίστας Forbes 7](#_Toc435789676)

[Συνδυασμός Πηγών 8](#_Toc435789677)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 8](#_Toc435789678)

[Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ 8](#_Toc435789679)

[Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ 8](#_Toc435789680)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015 9](#_Toc435789681)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ 10](#_Toc435789682)

[Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ 12](#_Toc435789683)

# Πρόλογος

Σε αυτό το έγγραφο παρουσιάζεται η Οντολογία του LinkedEconomy η οποία προτείνεται για τη μοντελοποίηση της εκάστοτε πηγής. Παρουσιάζονται και περιγράφονται οι Κλάσεις, οι Ιδιότητες Αντικειμένων και οι Ιδιότητες Τύπου Δεδομένων των οντολογιών καθώς και παραδείγματα SPARQL ερωτημάτων με ένα δείγμα απαντήσεών τους. Κατά την αναπαράσταση των κλάσεων και των ιδιοτήτων χρησιμοποιούνται κάποια συγκεκριμένα namespaces και prefixes τα οποία παρουσιάζονται στον Πίνακα 1 μαζί με την οντολογία ή το λεξικό στο οποίο αντιστοιχούν.

|  |  |  |
| --- | --- | --- |
| Prefix | URI | Ontology / Vocabulary |
| rdf | http://www.w3.org/1999/02/22-rdf-syntax-ns# | RDF |
| rdfs | http://www.w3.org/2000/01/rdf-schema# | RDFS |
| xsd | http://www.w3.org/2001/XMLSchema# | XSD |
| gr | http://purl.org/goodrelations/v1# | Good Relations |
| pc | http://purl.org/procurement/public-contracts# | Public Contracts |
| foaf | http://xmlns.com/foaf/0.1/# | FOAF |
| org | http://www.w3.org/ns/org# | Organization |
| rov | http://www.w3.org/ns/regorg# | Registered Organization |
| dc | http://purl.org/dc/elements/1.1/ | Dublin Core |
| dcterms | http://purl.org/dc/terms/ | Dublin Core Terms |
| skos | http://www.w3.org/2004/02/skos/core# | SKOS |
| vCard | http://www.w3.org/2006/vcard/ns# | vCard |
| dbo | http://dbpedia.org/ontology/ | DBpedia |
| elod | http://linkedeconomy.org/ontology# | Linked Economy |
| elodGeo | http://linkedeconomy.org/geoOntology# | Linked Economy Geo |

Πίνακας 1: Τα prefixes και οι οντολογίες/λεξιλόγια στις οποίες ανήκουν

# Forbes 2000

## Κλάσεις (Classes)

### FOAF

* foaf:Agent: Αυτή η κλάση αναπαριστά τις οντότητες οι οποίες συμμετέχουν σε δράσεις.
* foaf:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Good Relations

* gr:BusinessEntity: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Organization

* org:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### SKOS

* skos:Concept: Αυτή η κλάση αντιπροσωπεύει τις μονάδες σκέψης - ιδέες, έννοιες, ή (κατηγορίες) αντικειμένων και γεγονότων - τα οποία κρύβονται πίσω από πολλά συστήματα οργάνωσης γνώσης.

### Registered Organization

* rov:RegisteredOrganization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Linked Economy

* elod:Currency: Αυτή η κλάση αναπαριστά τα νομίσματα.
* elod:ForbesIndustry: Αυτή η κλάση αναπαριστά τομείς επιχειρισιακής δραστηριότητας όπως καταγράφεατι στη λίστα Forbes.
* elod:ForbesSector: Αυτή η κλάση αναπαριστά τη βιομηχανία στην οποία δραστηριοποιείται μία επιχείρηση όπως καταγράφεται στη λίστα Forbes.
* elod:Fundamental: Αυτή η κλάση αναπαριστά τις βασικές πληροπφορίες μίας επιχείρηση όπως καταγράφεται στη λίστα Forbes.
* elod:Rank: Αυτή η κλάση αναπαριστά την κατάταξη των πρακτόρων σύμφωνα με διάφορα κριτήρια.

### Linked Economy Geo

* elodGeo:Country: Αυτή η κλάση αναπαριστά τις χώρες.

## Ιδιότητες Αντικειμένων (Object Properties)

### Linked Economy

* elod:hasCurrency: Αυτή η ιδιότητα καθορίζει το νόμισμα για τα ποσά που ορίζονται από το elod:Fundamental.
* elod:isRegisteredAt: Αυτή η ιδιότητα συσχετίζει έναν πράκτορα με τη χώρα στην οποία έχει καταχωρηθεί.
* elod: relatesTo: Αυτή η ιδιότητα συσχετίζει μία επιχείρηση με κωδικό ISIN με μία άλλη από την βάση μας η οποία έχει ΑΦΜ.
* elod:hasFundamentals: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο των κλάσεων που ορίζουν τις επιχειρήσεις με ένα της elod:Fundamental.
* elod:hasRank: Αυτή η ιδιότητα συσχετίζει στιγμιότυπα διαφόρων κλάσεων με ένα της elod:Rank.
* elod:industry: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο των κλάσεων που ορίζουν τις επιχειρήσεις με ένα της elod:ForbesIndustry.
* elod:sector: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο των κλάσεων που ορίζουν τις επιχειρήσεις με ένα της elod:ForbesSector.

## Ιδιότητες Τύπου Δεδομένων (Datatype Properties)

### Good Relations

* gr:name: Το όνομα ενός στιγμιοτύπου της foaf:Agent όπως καταχωρήθηκε στην πηγή. Μπορεί να συνοδεύεται απ ένδειξη γλώσσας.

### SKOS

* skos:prefLabel: Αυτή η ιδιότητα παρέχει την προτιμώμενη λεξικολογική ετικέτα για έναν πόρο, σε μια δεδομένη γλώσσα.

### Linked Economy

* elod:isin: Ο κωδικός ISIN μίας επιχείρησης.
* elod:forbesWebPage: Η ιστοσελίδα του Forbes μίας επιχείρησης.
* elod:assets: Τα περιουσιακά στοιχεία μίας επιχείρησης της λίστας Forbes.
* elod:marketValue: Η εμπορική αξία μίας επιχείρησης της λίστας Forbes.
* elod:profits: Τα κέρδη μίας επιχείρησης της λίστας Forbes.
* elod:sales: Οι πωλήσεις μίας επιχείρησης της λίστας Forbes.
* elod:rank: Η κατάταξη ενός πράκτορα σύμφωνα με κάποια κριτήρια.
* elod:referenceYear: Το έτος για το οποίο αναφέρεται κάποια ένδειξη.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Στοιχεία Εταιρείας της λίστας Forbes

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

SELECT ?isin ?name ?registeredAt ?forbesWebPage ?rank (xsd:decimal(?profits) AS ?profits) (xsd:decimal(?assets) AS ?assets) (xsd:decimal(?sales) AS ?sales) (xsd:decimal(?marketValue) AS ?marketValue) ?sector ?industry ?referenceYear

FROM <http://linkedeconomy.org/Forbes>

WHERE {

#company

<http://linkedeconomy.org/resource/Organization/GB00BH4HKS39> elod:isin ?isin ;

gr:name ?name ;

elod:isRegisteredAt ?registeredAt ;

elod:forbesWebPage ?forbesWebPage ;

elod:hasRank ?rankRes ;

elod:hasFundamentals ?fundamentalsRes ;

elod:sector ?sector ;

elod:industry ?industry .

#rank

?rankRes elod:rank ?rank ;

elod:referenceYear ?referenceYear .

#fundamentals

?fundamentalsRes elod:hasCurrency ?hasCurrency ;

elod:assets ?assets ;

elod:profits ?profits ;

elod:sales ?sales ;

elod:marketValue ?marketValue .

}

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Όνομα Πεδίου** | **Τιμή** |
| **ISIN** | GB00BH4HKS39 |
| **Όνομα** | Vodafone |
| **Χώρα** | http://linkedeconomy.org/resource/Organization/GB |
| **Ιστοσελίδα Forbes** | http://www.forbes.com/companies/vodafone/ |
| **Θέση** | 38 |
| **Κέρδη** | 31800000512 |
| **Περιουσιακά Στοιχεία** | 235600003072 |
| **Πωλήσεις** | 65100001280 |
| **Αξία** | 96899997696 |
| **Τομέας** | http://linkedeconomy.org/resource/ForbesSector/TelecommunicationServices |
| **Βιομηχανία** | http://linkedeconomy.org/resource/ForbesIndustry/TelecommunicationsServices |
| **Έτος Αναφοράς** | 2015 |

### Σχετιζόμενες Εταιρειες Εταιρείας της λίστας Forbes

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

SELECT ?name ?isin ?relatedUri

FROM <http://linkedeconomy.org/Forbes>

WHERE {

<http://linkedeconomy.org/resource/Organization/US4592001014> elod:isin ?isin ;

gr:name ?name ;

elod:relatesTo ?relatedUri .

}

Αποτελέσματα ερωτήματος

|  |  |  |
| --- | --- | --- |
| **Όνομα** | **ISIN** | **Σχετιζόμενη Εταιρεία** |
| IBM | US4592001014 | http://linkedeconomy.org/resource/Organization/79000024733 |
| IBM | US4592001014 | http://linkedeconomy.org/resource/Organization/85001538736 |
| IBM | US4592001014 | http://linkedeconomy.org/resource/Organization/79000164938 |
| IBM | US4592001014 | http://linkedeconomy.org/resource/Organization/82002909248 |
| IBM | US4592001014 | http://linkedeconomy.org/resource/Organization/53069307286 |

### Πλήθος Σχετιζόμενων Εταιρειών Εταιρείας της λίστας Forbes

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

SELECT ?company ?name ?isin (COUNT(DISTINCT ?relatedUri) AS ?relatedUriCounter)

FROM <http://linkedeconomy.org/Forbes>

WHERE {

?company elod:isin ?isin ;

gr:name ?name ;

elod:relatesTo ?relatedUri .

}

GROUP BY ?company ?name ?isin

ORDER BY DESC (?relatedUriCounter)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |
| --- | --- | --- | --- |
| **Εταιρεία** | **Όνομα Εταιρεία** | **ISIN** | **Αριθμός Σχετιζόμε-νων Εταιρειών** |
| http://linkedeconomy.org/resource/Organization/GB00BH4HKS39 | Vodafone | GB00BH4HKS39 | 16 |
| http://linkedeconomy.org/resource/Organization/US0003752047 | ABB | US0003752047 | 14 |
| http://linkedeconomy.org/resource/Organization/US8835561023 | Thermo Fisher Scientific | US8835561023 | 12 |
| http://linkedeconomy.org/resource/Organization/US9841211033 | Xerox | US9841211033 | 11 |
| http://linkedeconomy.org/resource/Organization/GB0002634946 | BAE Systems | GB0002634946 | 10 |

# Συνδυασμός Πηγών

Η οντολογία προκύπτει από τη συνένωση των οντολογικών σχημάτων που περιγράφηκαν για τις παρακάτω πηγές: Διαύγεια, ΚΗΜΔΗΣ, ΕΣΠΑ και ΧΑΑ. Οι περιγραφή των κλάσεων και των ιδιοτήτων μπορούν να βρεθούν στις αντίστοιχες υποενότητες.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT DISTINCT ?seller

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller ?seller .

#KHMDHS

?cntr elod:seller ?seller ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary ?seller ;

rdf:type elod:Subsidy.

}

LIMIT 10

Αποτελέσματα ερωτήματος

|  |
| --- |
| **Ανάδοχος** |
| http://linkedeconomy.org/resource/Organization/082993120 |
| http://linkedeconomy.org/resource/Organization/094311705 |
| http://linkedeconomy.org/resource/Organization/102478909 |
| http://linkedeconomy.org/resource/Organization/032502798 |
| http://linkedeconomy.org/resource/Organization/101940406 |
| http://linkedeconomy.org/resource/Organization/082785679 |
| http://linkedeconomy.org/resource/Organization/082964412 |
| http://linkedeconomy.org/resource/Organization/800324752 |
| http://linkedeconomy.org/resource/Organization/094407125 |
| http://linkedeconomy.org/resource/Organization/090071277 |

### Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?name (COUNT(DISTINCT(?expAppr)) AS ?expApprDiavgeia) (COUNT(DISTINCT(?cntr)) AS ?cntrKhmdhs) (COUNT(DISTINCT(?subsidy)) AS ?subsidyEspa)

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> .

#KHMDHS

?cntr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type elod:Subsidy.

#Name

<http://linkedeconomy.org/resource/Organization/800332672> gr:legalName ?name ;

gr:vatID ?vatID .

}

Αποτελέσματα ερωτήματος

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **Ανάδοχος** | **ΑΦΜ** | **Εγκρίσεις Δαπανών** | **Συμβόλαια** | **Επιδοτήσεις** |
| FARGECO HELLAS ΣΥΛΛΟΓΗ ΕΠΕΞΕΡΓΑΣΙΑ ΑΠΟΡΡΙΜΜΑΤΩΝ ΕΤΑΙΡΕΙΑ ΠΕΡΙΟΡΙΣΜΕΝΗΣ ΕΥΘΥΝΗΣ ||FARGECO HELLAS ΕΠΕ | 800332672 | 6 | 13 | 1 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?company ?nameEn ?isin ?relatedUri (SUM(xsd:decimal(?amount)) AS ?totalAmountB22) (COUNT(DISTINCT ?payment) AS ?totalB22)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#Diavgeia

?payment elod:hasExpenditureLine ?expenditureLine ;

dcterms:issued ?date ;

rdf:type elod:SpendingItem .

?expenditureLine elod:seller ?relatedUri ;

elod:amount ?ups .

?ups gr:hasCurrencyValue ?amount .

FILTER (?date >= "2015-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?date < "2016-01-01T00:00:00Z"^^xsd:dateTime) .

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?totalAmountB22)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Εταιρεία** | **Όνομα** | **Κωδικός ISIN** | **Σχετιζόμενη Εταιρεία** | **Συνολικό Ποσό** | **Πλήθος Πράξεων** |
| http://linkedeconomy.org/resource/Organization/GRS434003000 | Public Power Corporation S.A. | GRS434003000 | http://linkedeconomy.org/resource/Organization/090000045 | 219446050 | 8939 |
| http://linkedeconomy.org/resource/Organization/GRS323003004 | EFG Eurobank Ergasias SA | GRS323003004 | http://linkedeconomy.org/resource/Organization/094014250 | 99599986 | 866 |
| http://linkedeconomy.org/resource/Organization/GRS414003004 | Agricultural Bank Of Greece S.A. | GRS414003004 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS014003008 | Piraeus Bank SA | GRS014003008 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS359353000 | Athens Water Supply & Sewage Co. | GRS359353000 | http://linkedeconomy.org/resource/Organization/094079101 | 35090079 | 1819 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

SELECT ?company ?nameEn ?isin ?relatedUri (COUNT(?subsidy) AS ?subsidyCounter) (SUM(xsd:decimal(?biAmount)) AS ?biAmount) (SUM(xsd:decimal(?cntrAmount)) AS ?cntrAmount) (SUM(xsd:decimal(?siAmount)) AS ?siAmount)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#ESPA

?subsidy elod:hasRelatedBudgetItem ?budgetItem ;

elod:hasRelatedContract ?contract ;

elod:hasRelatedSpendingItem ?spendingItem ;

elod:beneficiary ?relatedUri .

#budgetItem

?budgetItem elod:price ?biUps .

?biUps gr:hasCurrencyValue ?biAmount .

#contract

?contract pc:agreedPrice ?cntrUps .

?cntrUps gr:hasCurrencyValue ?cntrAmount.

#spendingItem

?spendingItem elod:amount ?siUps .

?siUps gr:hasCurrencyValue ?siAmount.

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?siAmount)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Όνομα Πεδίου** | **Τιμές** | | | | |
| **Εταιρεία** | http://linkedeconomy.org/resource/Organization/GRS496003005 | http://linkedeconomy.org/resource/Organization/GRS271101008 | http://linkedeconomy.org/resource/Organization/GRS221103005 | http://linkedeconomy.org/resource/Organization/GRS469003024 | http://linkedeconomy.org/resource/Organization/GRS384003000 |
| **Όνομα** | "Terna Energy S.A."@en | "Elval - Hellenic Aluminium Industry S.A."@en | "Hellenic Cables S.A."@en | "Kri-Kri S.A."@en | "Kordellos CH. Bros S.A."@en |
| **Κωδικός ISIN** | "GRS496003005" | "GRS271101008" | "GRS221103005" | "GRS469003024" | "GRS384003000" |
| **Σχετιζόμε-νη Εταιρεία** | http://linkedeconomy.org/resource/Organization/094006030 | http://linkedeconomy.org/resource/Organization/094100416 | http://linkedeconomy.org/resource/Organization/094039428 | http://linkedeconomy.org/resource/Organization/094289571 | http://linkedeconomy.org/resource/Organization/094130887 |
| **Πλήθος Επιδοτή-σεων** | 9 | 4 | 2 | 6 | 1 |
| **Ποσό Προϋπολο-γισμού** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Συμβο-λαίου** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Πληρωμής** | 20102736 | 6565140 | 4917724 | 3569338 | 2687320 |

### Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?company ?nameEn ?isin ?relatedUri ?payment ?signatureDate ?buyer ?buyerLegalName ?cpvEnglishSubject ?description ?amountOfThisGood ?unitOfMeasurement ?prodLabel (xsd:decimal(?amount) AS ?amount) ?vatPercentage (xsd:decimal((1+?vatPercentage/100)\*?amount) AS ?amountInclVat)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://publicspending.net/DiavgeiaI/CPV>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/ASE>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#KHMDHS

?payment elod:buyer ?buyer ;

pc:item ?offering ;

elod:signatureDate ?signatureDate .

#offering

?offering gr:includesObject ?tqn ;

gr:hasPriceSpecification ?ups ;

elod:seller ?relatedUri .

#tqn

?tqn gr:typeOfGood ?someItems ;

gr:amountOfThisGood ?amountOfThisGood ;

gr:hasUnitOfMeasurement ?unitOfMeasurement .

#ups

?ups elod:hasVat ?vat ;

gr:hasCurrencyValue ?amount .

#someItems

?someItems elod:productCategory ?cpv ;

gr:description ?description ;

elod:producedAt ?producedAt .

?buyer gr:legalName ?buyerLegalName .

?vat elod:vatPercentage ?vatPercentage .

?cpv elod:cpvEnglishSubject ?cpvEnglishSubject .

?producedAt skos:prefLabel ?prodLabel .

FILTER(LANGMATCHES(LANG(?prodLabel), "el")) .

FILTER NOT EXISTS {?payment elod:hasCorrectedDecision ?correctedDec } .

}

ORDER BY DESC (?amountInclVat)

LIMIT 1

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Όνομα Πεδίου** | **Τιμή** |
| **URI** | http://linkedeconomy.org/resource/Organization/GRS432003010 |
| **Όνομα** | "Intracom Constructions S.A.TECHN & Steel CONSTR."@en |
| **Κωδικός ISIN** | "GRS432003010" |
| **Σχετιζόμενο URI** | <http://linkedeconomy.org/resource/Organization/094207780> |
| **Πληρωμή** | <http://linkedeconomy.org/resource/Contract/13PAY001776162> |
| **Ημ/νια Υπογραφής** | 2013-12-11+03:00 |
| **Φορέας** | <http://linkedeconomy.org/resource/Organization/997612598> |
| **Όνομα Φορέα** | "ΠΕΡΙΦΕΡΕΙΑ ΚΕΝΤΡΙΚΗΣ ΜΑΚΕΔΟΝΙΑΣ"@el |
| **Περιγραφή CPV** | "Road construction works" |
| **Περιγραφή Πληρωμής** | Κατασκευή οδικού τμήματος Ποτίδαια- Κασσανδρεία του οδικού κυκλώματος Κασσάνδρας Ν. Χαλκιδικής (Υπογράφων σύμβασης Μπέκας Παύλος Δ/ντης ΔΕΚΕ ΠΚΜ) |
| **Ποσότητα** | 1.0 |
| **Μονάδα Μέτρησης** | Service |
| **Χώρα Προέλευσης** | "Ελλάδα"@el |
| **Ποσό (χωρίς ΦΠΑ)** | 41920968 |
| **ΦΠΑ** | 23.0 |
| **Ποσό (με ΦΠΑ)** | 51562791.43 |